TMS320LF2407事件管理器定時器1中斷系統(tǒng)實(shí)驗(yàn)

　　1、掌握TMS320LF2407事件管理器定時器1中斷系統(tǒng)的工作原理

　　2、掌握TMS320LF2407事件管理器定時器1的程序設(shè)計(jì)

　　TMS320LF2407有6個可屏蔽的中斷級，為了正確地響應(yīng)中斷，可以分兩步來完成中斷服務(wù)子程序。例如，當(dāng)優(yōu)先級INT2上的一個中斷請求被響應(yīng)時，CPU轉(zhuǎn)移至GISR2且執(zhí)行，一進(jìn)入GISR2就執(zhí)行保護(hù)現(xiàn)場操作，再讀取被鎖存在外設(shè)中斷向量寄存器（PIVR）中的該中斷事件的向量地址偏移量，根據(jù)向量地址偏移量在跳到響應(yīng)的中斷服務(wù)子程序（SISR）。

　　下面的實(shí)驗(yàn)程序是定時器1產(chǎn)生上溢、下溢、比較和周期中斷，在中斷服務(wù)子程序中分別點(diǎn)亮IOPB0、IOPB1、IOPB2和IOPB3輸出的指示燈。

　　;（1）建立中斷向量表

　　.sect ".vectors" ;定義主向量段

　　RSVECT B _c_int0 ;PM 0 Reset Vector 1

　　INT1 B PHANTOM ;PM 2 Int level 1 4

　　INT2 B GISR2 ;PM 4 Int level 2 5

　　INT3 B PHANTOM ;PM 6 Int level 3 6

　　INT4 B PHANTOM ;PM 8 Int level 4 7

　　INT5 B PHANTOM ;PM A Int level 5 8

　　INT6 B PHANTOM ;PM C Int level 6 9

　　RESERVED B PHANTOM ;PM E (Analysis Int) 10

　　SW_INT8 B PHANTOM ;PM 10 User S/W int —

　　SW_INT9 B PHANTOM ;PM 12 User S/W int —

　　SW_INT10 B PHANTOM ;PM 14 User S/W int —

　　SW_INT11 B PHANTOM ;PM 16 User S/W int —

　　SW_INT12 B PHANTOM ;PM 18 User S/W int —

　　SW_INT13 B PHANTOM ;PM 1A User S/W int —

　　SW_INT14 B PHANTOM ;PM 1C User S/W int —

　　SW_INT15 B PHANTOM ;PM 1E User S/W int —

　　SW_INT16 B PHANTOM ;PM 20 User S/W int —

　　TRAP B PHANTOM ;PM 22 Trap vector —

　　NMI B PHANTOM ;PM 24 Non maskable Int 3

　　EMU_TRAP B PHANTOM ;PM 26 Emulator Trap 2

　　SW_INT20 B PHANTOM ;PM 28 User S/W int —

　　SW_INT21 B PHANTOM ;PM 2A User S/W int —

　　SW_INT22 B PHANTOM ;PM 2C User S/W int —

　　SW_INT23 B PHANTOM ;PM 2E User S/W int —

　　SW_INT24 B PHANTOM ;PM 30 User S/W int —

　　SW_INT25 B PHANTOM ;PM 32 User S/W int —

　　SW_INT26 B PHANTOM ;PM 34 User S/W int —

　　SW_INT27 B PHANTOM ;PM 36 User S/W int —

　　SW_INT28 B PHANTOM ;PM 38 User S/W int —

　　SW_INT29 B PHANTOM ;PM 3A User S/W int —

　　SW_INT30 B PHANTOM ;PM 3C User S/W int —

　　SW_INT31 B PHANTOM ;PM 3E User S/W int —

　　.title "ev test routine"

　　.include "F2407REGS.H "

　　.include "vectors.h"

　　.def _c_int0

　　.sect ".text"

　　 .text

　　_c_int0: LDP #0H

　　SETC INTM ;關(guān)中斷

　　SPLK #0000H,IMR ;屏蔽所有中斷

　　LACC IFR ;讀中斷標(biāo)志

　　SACL IFR ;清中斷標(biāo)志

　　LDP #0E0H

　　SPLK #0004H,SCSR1 ;使能EVA模塊時鐘

　　SPLK #00E8H, WDCR ;禁止 WD

　　MAR *, AR0

　　LDP #0E1H

　　SPLK #00H,MCRA

　　SPLK #0FF00H,PBDATDIR ;設(shè)置IOPBN為輸出 ,0

　　LDP #0E8H

　　SPLK #0000H,GPTCONA

　　SPLK #0000H,T1CNT ;定時器計(jì)數(shù)為0

　　SPLK #0F4EH,T1CON ;000 01 連續(xù)增減計(jì)數(shù)模式

　　;110 X/64

　　;01 定時器1計(jì)數(shù)器使能

　　;00 內(nèi)部時鐘

　　;00 當(dāng)計(jì)數(shù)值為0時重裝

　　;1 定時器1比較使能

　　;0 使用自身的周期寄存器

　　SPLK #0FFFFH,T1PR

　　SPLK #8000H,T1CMPR

　　SPLK #0780H,EVAIMRA ;使能OV,U,C,P 中斷位

　　SPLK #0780H,EVAIFRA ;清中斷標(biāo)志

　　LDP #0H

　　SPLK #0002H,IMR

　　CLRC INTM ;開INT2中斷

　　WAIT: NOP ;等中斷

　　NOP

　　B WAIT

　　GISR2: NOP ;INT2 GISR

　　LDP #PIVR>>7H

　　LACL PIVR ;讀PIVR 值

　　XOR #002AH ;T1 上溢中斷

　　BCND SISR2A,eq

　　LACL PIVR

　　XOR #0029H ;T1 下溢中斷

　　BCND SISR29,eq

　　LACL PIVR

　　XOR #0028H ;T1 比較中斷

　　BCND SISR28,eq

　　LACL PIVR

　　XOR #0027H ;T1 周期中斷

　　BCND SISR27,eq

　　RET

　　SISR2A:

　　LDP #0E1H

　　SPLK #0FFFEH,PBDATDIR ;置低IOPBO

　　CALL DELAY

　　LDP #GPTCONA >>7h

　　LACC #0400H ;清上溢中斷標(biāo)志

　　SACL EVAIFRA

　　CLRC INTM ;開中斷

　　RET

　　SISR29:

　　LDP #0E1H

　　SPLK #0FFFDH,PBDATDIR ;置低IOPB1

　　CALL DELAY

　　LDP #GPTCONA >>7h

　　LACC #0200H ;清下溢中斷標(biāo)志

　　SACL EVAIFRA

　　CLRC INTM ;開中斷

　　RET

　　SISR28:

　　LDP #0E1H

　　SPLK #0FFFBH,PBDATDIR ;置低IOPB2

　　CALL DELAY

　　LDP #GPTCONA >>7h

　　LACC #0100H ;清比較中斷標(biāo)志

　　SACL EVAIFRA

　　CLRC INTM ;開中斷

　　RET

　　SISR27:

　　LDP #0E1H

　　SPLK #0FFF7H,PBDATDIR ;置低IOPB3

　　CALL DELAY

　　LDP #GPTCONA >>7h

　　LACC #0080H ;清周期中斷標(biāo)志

　　SACL EVAIFRA

　　CLRC INTM ;開中斷

　　RET

　　PHANTOM:

　　RET

　　DELAY:

　　LAR AR0,#0F000H ;延時子程序

　　D_LOOP:

　　RPT #05H

　　NOP

　　BANZ D_LOOP

　　RET

　　.end