led點陣顯示實驗

led點陣顯示實驗

led點陣顯示實驗實驗要求

利用實驗系統(tǒng)提供的實驗模塊點陣顯示，編程實現(xiàn)中英文字符的顯示。

led點陣顯示實驗實驗目的

1.了解LED點陣顯示的基本原理和實現(xiàn)方法。

2.掌握點陣漢字庫的編碼和從標準字庫中提取漢字編碼的方法。

led點陣顯示實驗電路及連線

點陣顯示模塊WTD3088的（紅色）列輸入線接至內部LED的陰極端，行輸入線接至內部LED的陽極端（若陽極端輸入為高電平，陰極端輸入低電平，則該LED點亮）。發(fā)光點的分布如圖22-0所示。
        
             Fig 22-0 WTD3088 LED分布
如圖22-1示，本實驗模塊使用74LS374來控制列輸入線的電平值。將74LS374的某輸出置0，則對應的LED陰極端被置低。如圖22-2示，本實驗模塊使用74LS273來控制行輸入線，并通過9013提供電流驅動。將74LS273的某輸出置1，則對應的LED陽極端被置高。每次系統(tǒng)重新開啟或總清后，74LS273輸出為全0，LED顯示被關閉。

通過編程控制各顯示點對應LED陽極和陰極端的電平，就可以有效的控制各顯示點的亮滅。

 
                Fig 22-1 LED模塊及列掃描電路
 

                    Fig 22-2 行掃描電路

 

                    Fig 22-3地址譯碼電路

本實驗模塊使用4塊WTD3088組成16×16點陣，以滿足漢字顯示的要求。為了方便的控制四個單元，使用了一片74LS139譯碼，產(chǎn)生四個地址片選信號：CLKR1= CSLED，CLKR2= CSLED+1，用于行控制的兩片74LS273；CLKC1= CSLED+2，CLKC2= CSLED+3，用于列控制的兩片74LS374。
實驗接線:按示例程序，模塊的CSLED接51/96地址的8000H。

led點陣顯示實驗說明

使用高亮度LED發(fā)光管構成點陣，通過編程控制可以顯示中英文字符、圖形及視頻動態(tài)圖形。LED顯示以其組構方式靈活、亮度高、技術成熟、成本低廉等特點在證券、運動場館及各種室內/外顯示場合得到廣泛的應用。

所顯示字符的點陣數(shù)據(jù)可以自行編寫（即直接點陣畫圖），也可從標準字庫（如ASC16、HZ16）中提取。后者需要正確掌握字庫的編碼方法和字符定位的計算。

實驗盤片中“字符轉換”子目錄下提供的Basc16.exe,BHz16.exe可方便的將單個字符的碼表從標準字庫Asc16,Hzk16中提取出來。具體使用方法是運行上述可執(zhí)行程序，根據(jù)提示輸入所需字符（如是漢字還需要先啟動dos下的漢字環(huán)境，如ucdos，pdos95等）。程序將該字符的碼表提取出來，存放在該字符ASC或區(qū)位碼為文件名稱的.dat文件中。用戶只需將該文件中內容拷貝、粘貼到自己的程序中即可。但需要注意字節(jié)排列順序、字節(jié)中每一位與具體顯示點的一一對應關系，必要時還要對碼表稍作修改。同一目錄下還提供了上述可執(zhí)行程序的源文件，使用BC3.1編寫，供用戶參考。

led點陣顯示實驗程序框圖

            
      
       用戶應留心其中行掃描的實現(xiàn)及碼表的處理。
led點陣顯示實驗程序：

（一）提供LEDA51演示Asc16字符的簡單點陣顯示。
;*********LED 點陣顯示示例程序***********************
;** 該程序顯示 Asc16字符 **
;** 為了簡單起見，程序只顯示一個字符 **
;** 該程序針對T598實驗機的模塊14 **
;****************************************************

CSLED EQU 8000H 
CSR1 EQU CSLED ;行1 273
CSR2 EQU CSLED+1H ;行2 273
CSC1 EQU CSLED+2H ;列1 374
CSC2 EQU CSLED+3H ;列2 374

ORG 0000H

MOV SP,#60H
INIT: MOV A,#0H ;關閉行
MOV DPTR,#CSR1
MOVX @DPTR,A
MOV DPTR,#CSR2
MOVX @DPTR,A
MOV A,#0FFH ;關閉列
MOV DPTR,#CSC1
MOVX @DPTR,A
MOV DPTR,#CSC2
MOVX @DPTR,A

D: MOV R5,#00H
MOV R4,#01H ;每次為單行掃描
DISP: 
MOV A,R5
MOV DPTR,#ASCE ;此處設定所要顯示的字符
MOVC A,@A+DPTR
CPL ACC ;代碼取反,決定顯示的陰陽
MOV DPTR,#CSC2
MOVX @DPTR,A

MOV DPTR,#CSR1
MOV A,R4
MOVX @DPTR,A
RL ACC
MOV R4,ACC
INC R5
LCALL DELAY
CJNE R5,#8H,DISP 

MOV A,#0H
MOVX @DPTR,A

MOV R5,#08H
MOV R4,#01H
DISP2: 
MOV A,R5
MOV DPTR,#ASCE
MOVC A,@A+DPTR
CPL ACC
MOV DPTR,#CSC2
MOVX @DPTR,A

MOV DPTR,#CSR2
MOV A,R4
MOVX @DPTR,A
RL ACC
MOV R4,ACC
INC R5
LCALL DELAY
CJNE R5,#10H,DISP2 

MOV A,#0H
MOVX @DPTR,A

SJMP D
;******** 延時子程序,協(xié)調字符顯示速度 *************
DELAY: MOV R7,#1H
DL1: MOV R6,#00H
DL2: DJNZ R6,DL2
DJNZ R7,DL1
RET

;******** 字符點陣字庫 ***************
; ASC16 字符編碼排列
; 0
; 1
; |
; |
; 14
; 15
; 高位 D7--D0 
; 請注意編碼的排列次序和實際顯示點陣分布的關系 
ASCA:DB 00H,00H,10H,38H,6CH,0C6H,0C6H,0FEH
DB 0C6H,0C6H,0C6H,0C6H,00H,00H,00H,00H
ASCE:DB 00H,00H,0FEH,66H,62H,68H,78H,68H
DB 60H,62H,66H,0FEH,00H,00H,00H,00H
ASCD:DB 00H,00H,0F8H,6CH,66H,66H,66H,66H
DB 66H,66H,6CH,0F8H,00H,00H,00H,00H
ASCK:DB 00H,00H,0E6H,66H,66H,6CH,78H,78H
DB 6CH,66H,66H,0E6H,00H,00H,00H,00H
;****************************************************
END

（二）LEDHZ51兩個示例程序。和Hz16字符的簡單點陣顯示。
;*********LED 點陣顯示示例程序***********************
;** 該程序顯示 hz16字符 **
;** 為了簡單起見，程序只顯示一個字符 **
;** 該程序針對T598實驗機的模塊14 **
;****************************************************

CSLED EQU 8000H 
CSR1 EQU CSLED ;行1 273
CSR2 EQU CSLED+1H ;行2 273
CSC1 EQU CSLED+2H ;列1 374
CSC2 EQU CSLED+3H ;列2 374

ORG 0000H

MOV SP,#60H
INIT: MOV A,#0H ;關閉LED顯示
MOV DPTR,#CSR1
MOVX @DPTR,A
MOV DPTR,#CSR2
MOVX @DPTR,A
MOV A,#0FFH ;關閉LED顯示
MOV DPTR,#CSC1
MOVX @DPTR,A
MOV DPTR,#CSC2
MOVX @DPTR,A

D: MOV R5,#00H
MOV R4,#01H
DISP: 
MOV A,R5
RL ACC
MOV DPTR,#HZAI
MOVC A,@A+DPTR
CPL ACC
MOV DPTR,#CSC2
MOVX @DPTR,A

MOV A,R5
RL ACC
INC ACC
MOV DPTR,#HZAI
MOVC A,@A+DPTR
CPL ACC
MOV DPTR,#CSC1
MOVX @DPTR,A

MOV DPTR,#CSR1
MOV A,R4
MOVX @DPTR,A
RL ACC
MOV R4,ACC
INC R5
LCALL DELAY
CJNE R5,#8H,DISP 

MOV A,#0H
MOVX @DPTR,A

MOV R5,#08H
MOV R4,#01H
DISP2: 
MOV A,R5
RL ACC
MOV DPTR,#HZAI
MOVC A,@A+DPTR
CPL ACC
MOV DPTR,#CSC2
MOVX @DPTR,A

MOV A,R5
RL ACC
INC ACC
MOV DPTR,#HZAI
MOVC A,@A+DPTR
CPL ACC
MOV DPTR,#CSC1
MOVX @DPTR,A

MOV DPTR,#CSR2
MOV A,R4
MOVX @DPTR,A
RL ACC
MOV R4,ACC
INC R5
LCALL DELAY
CJNE R5,#10H,DISP2 

MOV A,#0H
MOVX @DPTR,A

SJMP D
;******** 延時子程序,協(xié)調字符顯示速度 *************
DELAY: MOV R7,#1H
DL1: MOV R6,#00H
DL2: DJNZ R6,DL2
DJNZ R7,DL1
RET
;******** 字符點陣字庫 ***************
; HZ16 字符編碼排列
; 0 1
; 2 3
; |
; |
; 28 29
; 30 31
; 高位 D7--D0 
HZAI:DB 00H,78H,3FH,80H,11H,10H,09H,20H
DB 7FH,0FEH,42H,02H,82H,04H,7FH,0F8H
DB 04H,00H,07H,0F0H,0AH,20H,09H,40H
DB 10H,80H,11H,60H,22H,1CH,0CH,08H

HZDI:DB 00H,80H,40H,80H,20H,88H,2FH,0FCH
DB 08H,88H,08H,88H,0E8H,88H,2FH,0F8H
DB 28H,88H,28H,88H,28H,88H,2FH,0F8H
DB 28H,08H,50H,06H,8FH,0FCH,00H,00H

HZKE:DB 01H,00H,01H,04H,0FFH,0FEH,01H,00H
DB 01H,10H,1FH,0F8H,10H,10H,10H,10H
DB 10H,10H,1FH,0F0H,14H,50H,04H,40H
DB 04H,40H,08H,42H,10H,42H,60H,3EH
;****************************************************
END