SWay使用GPS監(jiān)控孩子的地理位置

佩戴設(shè)備的孩子在到達學(xué)校、到家、到達目的地遲到或偏離路線時都會收到提醒

?

?

?

?

?

1 / 3 ?遲到（LED 橙色）

?

設(shè)備在行動

好處

使用此設(shè)備的家長將受益于：

• 確保他們的孩子安全往返學(xué)校
• 確保他們的孩子準時到達這些地點
• 確保他們的孩子不會偏離路線
• 節(jié)能和低成本 - 長效電池

建設(shè)項目

第 1 步：所需設(shè)備

要開始制作這個項目，我們需要收集材料。對于這個項目，您將需要：

• 跳線
• 1、NPN晶體管
• 1、陶瓷電容（0.1μF）
• 3、電阻器（220Ω）
• 1、電阻（1KΩ）
• 1、RGB LED
• 1、GPS模塊
• 1、振動電機單元
• 1、Arduino MKR1200狐貍
• 1、2x AAA/ AA 電池盒
• 2、AA電池

?

所有組件

?

第 2 步：連接電路

下一步是連接電路；下面的 Fritzing 圖像將說明這是如何完成的。布線有多個部分，因此它們被分成不同的圖像。

?

原理圖

?

第 3 步：確認代碼

代碼由多個函數(shù)組成，每個函數(shù)在項目的構(gòu)成中發(fā)揮特定的作用。

• 警告系統(tǒng)
• 獲取 GPS
• 同步實時時鐘
• 工藝位置
• 發(fā)送包裹
• 做動作

下面對這些部分進行說明。

• 警告系統(tǒng)

void setOutputs()
{
 pinMode(R, OUTPUT);
 pinMode(G, OUTPUT);
 pinMode(B, OUTPUT);
 pinMode(motorPin, OUTPUT);
}
void vibrateMotor() // vibrate the motor cell
{
 digitalWrite(motorPin, HIGH);
 delay(1000);
 digitalWrite(motorPin, LOW);
}
void ledGreen() // LED, Green
{
 analogWrite(R, 0);
 analogWrite(G, 255);
 analogWrite(B, 0);
}
void ledOrange() // LED, Orange
{
 analogWrite(R, 255);
 analogWrite(G, 45);
 analogWrite(B, 0);
}
void ledRed() // LED, Red
{
 analogWrite(R, 255);
 analogWrite(G, 0);
 analogWrite(B, 0);
}
void resetLED() // Turn off LED
{
 analogWrite(R, 0);
 analogWrite(G, 0);
 analogWrite(B, 0);
}

這部分代碼可以在functions.h文件中找到。該代碼將通知孩子在當(dāng)前狀態(tài)下佩戴該設(shè)備。總的來說，這些回路控制 RGB LED 和振動電機單元。

• 獲取 GPS

bool getGPS(int run)
{
 while(Serial1.available() > 0)
 {
   if(gps.encode(Serial1.read()))
   {
     if(run == 1)
     {
       processData();
     }
     else if(run == 2)
     {
       synchRTC();
     }
     if(gps.location.isValid() && gps.time.isValid() && gps.date.isValid())
     {
       return true;
     }
     else
     {
       return false;
     }
   }
 }
 if(millis() > 10000 && gps.charsProcessed() < 10)
 {
   Serial.println("Error - GPS Module Responded with Error");
   Serial.println("  Terminating Code");
   Serial.println("________________________________________");
   while(1) {};
 }
}

這是負責(zé)從 GPS 模塊接收位置和時間的循環(huán)。這個循環(huán)做了 3 件事，它用于setup loop同步 GPS，然后用于將板載 RTC 與 GPS 同步，并在主循環(huán)中用于獲取設(shè)備的地理位置。

• 同步實時時鐘

void synchRTC()
{
 Serial.println("Synching RTC");
 Serial.println("________________________________________");
 Serial.println("  OK - Initialising RTC");
 rtc.begin();
 Serial.println("  OK - Synching Time");
 // we have to trim the variable's first 2 digits (2018 -> 18)
 uint16_t yearRAW = gps.date.year();
 String yearString = String(yearRAW);
 yearString.remove(0,1);
 uint16_t year = yearString.toInt();
 rtc.setTime(gps.time.hour(), gps.time.minute(), gps.time.second());
 rtc.setDate(gps.date.day(), gps.date.month(), year);
 Serial.println("  Success - RTC Synched");
 Serial.println("________________________________________");
 Serial.println("");
 Serial.println("");
 Serial.println("");
}

這部分代碼將板載 RTC 與從 GPS 模塊接收到的時間同步，它首先從 GPS 模塊讀取數(shù)據(jù)然后對其進行處理。然后循環(huán)將板載 RTC 的當(dāng)前時間設(shè)置為接收到的時間并啟動 RTC。

• 工藝位置

bool processData()
{
 if(gps.location.isValid())
 {
   latitude = gps.location.lat();
   longitude = gps.location.lng();
   latitude = 53.355504;
   longitude = -6.258452;
   if(check.isOut())
   {
     if(check.track())
     {
       Serial.println("OUT OF BOUNDS");
       warn.offTrackLoop();
     }
   }
   if(check.isHomeTime() && arrivedSchool)
   {
     if(check.isHome())
     {
       Serial.println("AT HOME");
       warn.arrivedHomeLoop();
     }
     else
     {
       Serial.println("LATE -> HOME");
       warn.lateLoop();
     }
   }
   else if(check.isSchoolTime() && arrivedHome)
   {
     Serial.println(".");
     if(check.isSchool())
     {
       Serial.println("AT SCHOOL");
       warn.arrivedSchoolLoop();
     }
     else
     {
       Serial.println("LATE -> SCHOOL");
       warn.lateLoop();
     }
   }
   else
   {
     Serial.println("ON WAY");
   }
 }
}

該循環(huán)將處理設(shè)備的位置并將其與當(dāng)前時間進行比較，以查看此時孩子應(yīng)該在哪里。然后它將根據(jù)結(jié)果執(zhí)行適當(dāng)?shù)牟僮鳌?/font>

• 做動作

struct Do
{
 void offTrackLoop()
 {
   if(offTrackVar)
   {
     parseData(0);
   }
   vibrateMotor();
   ledRed();
   delay(1000);
   vibrateMotor();
   resetLED();
   offTrackVar = true;
   delay(120000);
 }
 void lateLoop()
 {
   if(!lateVar)
   {
     parseData(1);
   }
   vibrateMotor();
   ledOrange();
   delay(1000);
   resetLED();
   lateVar = true;
 }
 void arrivedHomeLoop()
 {
   lateVar = false;
   offTrackVar = false;
   vibrateMotor();
   ledGreen();
   delay(1000);
   resetLED();
   parseData(2);
   arrivedHome = true;
   arrivedSchool = false;
 }
 void arrivedSchoolLoop()
 {
   lateVar = false;
   offTrackVar = false;
   vibrateMotor();
   ledGreen();
   delay(1000);
   resetLED();
   parseData(3);
   arrivedHome = false;
   arrivedSchool = true;
 }
};

調(diào)用此結(jié)構(gòu)以對Process Location給出的響應(yīng)采取行動，它會警告孩子切換 RGB LED 和振動電機單元。如有必要，它還會向 SigFox 發(fā)送一個包。

• 發(fā)送包裹

void parseData(int state)
{
 SigFox.beginPacket(); // begin the message sending process
 if(state == 0) // off track
 {
   SigFox.print("off track"); // send the message
 }
 else if(state == 1) // late
 {
   SigFox.print("late"); // send the message
 }
 else if(state == 2) // arrived home
 {
   SigFox.print("at home"); // send the message
 }
 else // arrived school
 {
   SigFox.print("at school"); // send the message
 }
 SigFox.endPacket();
}

該函數(shù)將數(shù)據(jù)發(fā)送到 SigFox，開始發(fā)送數(shù)據(jù)包，然后解析適當(dāng)?shù)闹怠?/font>

設(shè)置變量

代碼將包含多個變量，TODO 寫在它們之后作為注釋，這些變量必須自定義以適合客戶端，客戶端將被要求設(shè)置

• 上學(xué)時間
• 孩子旅行的時間
• 學(xué)校結(jié)束的時間
• 調(diào)試？
• 學(xué)校地理位置（LAT、LNG）；
• 家庭地理定位（LAT、LNG）；

下面的指南將指導(dǎo)您設(shè)置變量。

?

?

?

?

?

1 / 11 ?第一步是打開項目的代碼

?

圖書館

SigFox - 版權(quán)所有 (c) 2016 Arduino LLC GNU Lesser General Public License 此庫屬于公共領(lǐng)域

ctype - GNU 通用公共許可證下的版權(quán) (c) 2006 自由軟件基金會，該庫屬于公共領(lǐng)域

RTCZero - GNU Lesser General Public License 下的版權(quán) (c) 2015 Arduino LLC，該庫屬于公共領(lǐng)域

字符串 - 版權(quán)所有 (c) 2009-10 Hernando Barragan，版權(quán) (c) 2011 Paul Stoffrengen 在 GNU Lesser General Public License 下，該庫屬于公共領(lǐng)域

TinyGPS++ - 版權(quán)所有 (c) 2008-13 Mikal Hart 在 GNU Lesser General Public License 下，該庫屬于公共領(lǐng)域

設(shè)置

確保電路接線正確。有關(guān)設(shè)置 MKR fox 的詳細信息，請單擊此處查看Arduino 教程。如果您想了解有關(guān) Arduino SigFox 庫的更多信息，請單擊此處。

后端程序

您必須擁有注冊的 Arduino MKR1200 狐貍才能對后端進行編程。

• 步驟1

打開SigFox 后端并登錄您的 SigFox 帳戶。

• 第2步

點擊頁面頂部下拉菜單中的“設(shè)備類型”

?

單擊設(shè)備類型

?

• 第 3 步：

選擇您的 Arduino MKRfox 并單擊編輯

?

選擇您的板并單擊編輯

?

• 第4步：

從左側(cè)菜單中選擇回調(diào)，然后導(dǎo)航到右上角的“新建”按鈕。

?

選擇回調(diào)并單擊新建

?

• 第 5 步：

單擊新建后，您將看到一些回調(diào)配置選項，單擊自定義回調(diào)

?

?

接下來將打開一個窗口，您必須填寫給定的表格來創(chuàng)建您的回調(diào)

將類型設(shè)置為數(shù)據(jù)、上行鏈路

將頻道設(shè)置為電子郵件

自定義有效負載將讀取板發(fā)送的數(shù)據(jù)然后對其進行格式化，在我們的例子中，您必須聲明一個變量str ，:: 然后是變量類型char 和該變量占用的字符數(shù)10 。最后你應(yīng)該有這樣的東西str::char:10

將收件人設(shè)置為數(shù)據(jù)將發(fā)送到的電子郵件地址。

根據(jù)需要設(shè)置電子郵件的主題。

在消息字段中，您可以默認使用多個變量，無需從您的設(shè)備發(fā)送它們，我們將使用{device} （設(shè)備 ID）、{lat} （模塊的緯度）和{lng} （模塊的經(jīng)度），這些變量將自動發(fā)送到 SigFox到 12 個字節(jié)的有效負載中，因此您可以使用它們而無需專門從您的設(shè)備發(fā)送這些字符串。我們還將使用{customData#str} 這個變量來保存 Arduino MKR1200 fox 發(fā)送的數(shù)據(jù)，customData 指的是設(shè)備發(fā)送的個性化數(shù)據(jù)#str 表明設(shè)備將讀取設(shè)備str 發(fā)送的字符串。

我們還將添加一個網(wǎng)站來檢查接收到的坐標(biāo)，使用谷歌地圖，我們可以在地圖上精確定位接收到的數(shù)據(jù)。這是 url https://www.google.com/maps/?q={lat},{lng} ， lat 和 lng 將自動更改為緯度和經(jīng)度變量。

最后，您的消息應(yīng)如下所示：

?

回調(diào)配置

?

現(xiàn)在單擊確定，一切就緒。

最后

您需要做的最后一件事是上傳下面的代碼，確保您已根據(jù)自己的喜好自定義了標(biāo)有“TODO”的變量，等待 GOS 模塊上的藍燈閃爍，然后斷開微控制器與計算機的連接，然后將電池放入電池盒中。你都準備好了。

我設(shè)計了一個外殼來保證設(shè)備的安全并使其看起來更有吸引力，我使用了兩塊丙烯酸并將邊緣熔化成 90 度彎曲。我把所有的電路放在里面，把電池盒放在它們下面，然后用兩條電纜扎帶把塑料片綁在一起。

?

最后，我覆蓋了一塊頂部（透明蓋）以隱藏所有電線，只讓項目的大腦可見。

背景

我個人知道執(zhí)行送孩子上學(xué)的簡單任務(wù)會有多大壓力，每個人都擔(dān)心孩子上學(xué)時可能發(fā)生的所有事情。

該項目面向所有在送孩子上學(xué)時感到壓力的人。SWay 會讓您放松，因為您知道您的孩子會安全到達學(xué)校。

?

?

?