在MAX-IDE中自動初始化數(shù)據(jù)段

在MAX-IDE中自動初始化數(shù)據(jù)段

摘要：該應(yīng)用筆記討論了MAX-IDE提供的程序和數(shù)據(jù)段的靈活工具，用于MAXQ?微控制器的應(yīng)用編程。程序和數(shù)據(jù)段機制能夠在數(shù)據(jù)存儲器自動聲明變量位置，并以起始值對這些變量進(jìn)行初始化。應(yīng)用程序可以將這些變量值緩存在閃存內(nèi)，并在需要時恢復(fù)這些數(shù)據(jù)。該方法允許基于匯編語言的應(yīng)用程序充分利用MAX-IDE提供的數(shù)據(jù)段自動裝載功能，無論微控制器與JTAG調(diào)試器是否連接都能保持工作。MAXQ2000微控制器評估板能夠演示這一方案，本文給出了相應(yīng)的例程。

概述

MAXQ匯編程序的變量可以存儲在工作寄存器(例如累加器A[0]至A[15])或數(shù)據(jù)存儲器(SRAM)。在數(shù)據(jù)存儲器中存儲變量能夠為應(yīng)用程序變量提供較大的工作區(qū)域，但需要額外的訪問時間。

MaxQAsm編譯器和MAX-IDE環(huán)境提供單獨聲明程序段和數(shù)據(jù)段的機制，對各段產(chǎn)生各自的hex輸出文件。運行時，MAX-IDE自動將程序段文件裝載到程序存儲器(通常為閃存)，將數(shù)據(jù)段文件裝載到數(shù)據(jù)存儲器(通常為RAM)。然而，由于數(shù)據(jù)存儲器為易失存儲器，一旦微控制器掉電，將丟失數(shù)據(jù)段內(nèi)容。

本文利用MAXQ2000 EV (評估)板首先演示應(yīng)用程序開始運行時如何將預(yù)裝載數(shù)據(jù)存儲器值保存到閃存內(nèi)，隨后演示微控制器重新上電時如何從閃存刷新數(shù)據(jù)段。無論應(yīng)用程序處于開發(fā)階段(連接到JTAG適配器和MAX-IDE)還是在現(xiàn)場運行，這兩個步驟都允許使用相同的數(shù)據(jù)段機制聲明和初始化變量。

該應(yīng)用筆記的例程為MAXQ2000微控制器以及MAXQ2000評估板編寫，但相應(yīng)程序和原理適用于任何基于MAXQ20、能夠重新編程閃存的微控制器。

提供最新版本的安裝軟件和關(guān)于MAX-IDE環(huán)境的文檔，可免費下載。

• MAX-IDE安裝程序
• MAXQ核編譯指南
• 開發(fā)工具指南

變量和存儲位置

嵌入式應(yīng)用通常需要一定的工作區(qū)域存儲狀態(tài)信息、配置數(shù)據(jù)、中間數(shù)據(jù)、循環(huán)計數(shù)器以及計算結(jié)果。存儲在該工作區(qū)域的數(shù)據(jù)通常作為變量，具有以下特征。

1. 它們是臨時數(shù)據(jù)。如果應(yīng)用程序由于電源失效或復(fù)位產(chǎn)生中斷，不需要保存這些數(shù)據(jù)。
2. 它們可頻繁訪問和更新。它們必須存儲在能夠快速讀寫的位置；這些位置的寫入次數(shù)必須沒有限制。
3. 它們具有定義的初始值。程序開始運行時，用戶程序必須將它們設(shè)置為特定值。

用C語言或其它高級語言編寫的程序編譯成匯編代碼，編譯器通常自動為變量分配空間(同時將變量初始化為預(yù)先定義的起始值)。這種情況下，用戶只需聲明變量、變量類型及其初始值(可選)，其余工作由編譯器處理。

   unsigned int c = 0x1234;
   

然而，用MAXQ匯編語言編寫應(yīng)用程序時，必須明確指定變量分配空間并設(shè)置變量初始值。這些細(xì)節(jié)能夠嚴(yán)格控制MAXQ微控制器的資源，但增加了系統(tǒng)復(fù)雜性。

對于基于匯編的小型應(yīng)用程序或不需要大量工作區(qū)域的應(yīng)用程序，內(nèi)部寄存器可用來存儲所有應(yīng)用程序變量。這種方法具有兩個重要優(yōu)勢：

1. 程序結(jié)構(gòu)緊湊、運行速度快。根據(jù)寄存器位置，在一個指令周期內(nèi)可實現(xiàn)寄存器變量的讀取、寫入或復(fù)制其它寄存器變量。對基于MAXQ20的微控制器，在最差工作條件下，通常最多占用不超過兩個指令周期。
2. 直接操作變量?？芍苯硬僮饕恍﹥?nèi)部寄存器。例如，可以(使用AP寄存器)選擇16個工作累加器A[0]至A[15]的任何一個作為有效累加器Acc。這就意味著如果需要對這些寄存器存儲的一個變量進(jìn)行操作時，可直接對寄存器進(jìn)行操作，無需將數(shù)據(jù)復(fù)制出來進(jìn)行操作后再將數(shù)據(jù)復(fù)制回去。同樣，執(zhí)行djnz指令時，存儲在LC[0]和LC[1]寄存器的變量可直接作為循環(huán)計數(shù)器。

對于大規(guī)模應(yīng)用程序或者當(dāng)應(yīng)用程序需要大量工作變量時，可將其中一些或所有變量存儲在基于SRAM的數(shù)據(jù)存儲器。這種方式允許創(chuàng)建更多的變量，具體受限于數(shù)據(jù)存儲器的空間。按照這種方式存儲的變量可以通過MAXQ20核的標(biāo)準(zhǔn)數(shù)據(jù)指針訪問，該指針用于讀取或?qū)懭胱止?jié)寬度或字寬變量(注意：本應(yīng)用筆記的例程假定DP[0]配置為工作在字模式)。

   move   DP[0], #0010h      ; Location of variable in data memory
   move   Acc, @DP[0]        ; Read variable
   add    #1                 ; Increment variable value by 1
   move   @DP[0], Acc        ; Store variable back in data memory
   

當(dāng)對一個變量進(jìn)行一系列的較長計算操作時，可以將變量值首先復(fù)制到工作寄存器，如上述例程所示。所有中間操作可利用該工作寄存器執(zhí)行，完成計算后將變量值復(fù)制回來。

MAX-IDE的段聲明

決定在基于SRAM的數(shù)據(jù)存儲器存儲應(yīng)用程序變量時，如何確定變量的存儲地址?

通常，除了調(diào)試器使用的最高32個字節(jié)的存儲空間外，應(yīng)用程序可以使用其它所有數(shù)據(jù)存儲器。這意味著聲明一個變量即可定義其在數(shù)據(jù)存儲器中的位置。程序可通過該地址對變量進(jìn)行讀寫，用#define宏命令將變量地址和符號名稱關(guān)聯(lián)起來。

#define VarA  #0020h
#define VarB  #0021h
#define VarC  #0022h

   move   DP[0], VarA        ; Point to VarA variable
   move   Acc, @DP[0]        ; Read value of variable
   move   DP[0], VarB        ; Point to VarB variable
   move   @DP[0], Acc        ; Copy VarA to VarB
   move   DP[0], VarC        ; Point to VarC variable
   move   @DP[0], #1234h     ; Set VarC = 1234h

這種方案可以很好地工作，但是有幾個問題需要注意。

• 必須事先定義每個變量的地址，這項工作比較耗時，特別是確定隨后將所有變量移至不同的數(shù)據(jù)存儲區(qū)域時。
• 必須注意一個以上的變量不要占用同一地址，如果發(fā)生這種錯誤將很難追蹤這些故障。
• 變量的初始(開始)值必須通過應(yīng)用程序裝載，如上述程序的最后一行。如果有多個變量按照這種方式初始化將會占用大量的程序空間。

比較有效的方案是利用MAX-IDE機制分別聲明程序段和數(shù)據(jù)段。這種方法允許編程人員指定匯編程序的哪一部分定義為程序空間，哪一部分定義為數(shù)據(jù)空間。

segment code

   move  DP[0], #VarA       ; Point to VarA
   move  Acc, @DP[0]        ; Get current value of VarA
   add   #1                 ; Increment it
   move  @DP[0], Acc        ; Store value back in VarA

segment data

VarA:
   dw    0394h              ; Initial value for VarA

利用上述方案，在數(shù)據(jù)段聲明的變量地址由編譯器解析文件時自動指定，用同樣方法為程序空間分配地址標(biāo)簽。標(biāo)簽用于對變量地址指定符號名稱，dw和db聲明可以在初始化變量時用于設(shè)置字寬或字節(jié)寬度初始值。這種情況下，假定匯編文件中事先沒有segment data指令，編譯器將從0000h地址起始數(shù)據(jù)段。這意味著VarA將存儲在字地址0000h。對于程序空間，org聲明將強制變量從指定的起始地址開始存儲。

數(shù)據(jù)段初始化

在先前的程序清單中，變量VarA定義(用dw聲明)的初始值為0394h。但是，該值在程序中并不裝載到VarA。那么，如何初始化這一數(shù)值? 答案是在編譯和運行工程時，MAX-IDE將自動執(zhí)行數(shù)據(jù)段初始化。

MaxQAsm編譯器通過產(chǎn)生一個二級hex輸出文件響應(yīng)segment data指令。通常，為工程產(chǎn)生的hex文件包含程序數(shù)據(jù)。例如，如果編譯工程"example.prj"，將產(chǎn)生一個名稱為"example.hex"的hex文件，并包含通過編譯工程文件產(chǎn)生的程序數(shù)據(jù)。如果定義了數(shù)據(jù)段，則將產(chǎn)生一個名稱為"example_d.hex"的附加hex文件，該文件包含該段編譯數(shù)據(jù)。

執(zhí)行工程時，MAX-IDE檢查是否在工程編譯中產(chǎn)生了數(shù)據(jù)段文件(以_d.hex結(jié)尾)。如果存在數(shù)據(jù)段文件，MAX-IDE通過標(biāo)準(zhǔn)的JTAG裝載器將該段數(shù)據(jù)裝載到器件的數(shù)據(jù)SRAM。該過程在標(biāo)準(zhǔn)的hex文件裝載到程序存儲器之后執(zhí)行。

這種方案能夠很好地工作在開發(fā)階段，當(dāng)器件連接到JTAG適配器，在應(yīng)用程序運行之前，MAX-IDE重新裝載程序數(shù)據(jù)和段數(shù)據(jù)。但是，一旦器件掉電并重新上電，而且允許獨立運行(沒有連接調(diào)試器)，在每次運行前MAX-IDE將無法正確裝載數(shù)據(jù)段。變量也無法設(shè)置在所要求的數(shù)值，導(dǎo)致應(yīng)用程序不能正確執(zhí)行。這種故障很難分析，因為一旦器件重新連接到調(diào)試器，MAX-IDE將在每次運行前重新開始裝載數(shù)據(jù)段，問題也就消失了。

保存和恢復(fù)數(shù)據(jù)段

一個遺留問題是：如何使應(yīng)用程序在連接調(diào)試器(每次運行前MAX-IDE重新裝載程序和數(shù)據(jù))和獨立運行(上電后RAM內(nèi)容不確定)時都能保持工作。顯然，解決方法需要兩個步驟：應(yīng)用程序?qū)⒆兞恐?一旦經(jīng)過初始化)保存到閃存，每次復(fù)位或上電后重新裝載這些數(shù)值。

對于第一步，應(yīng)用程序必須將數(shù)值保存到閃存。每次主機擦除或裝載程序后第一次運行應(yīng)用程序時執(zhí)行該操作。

1. 應(yīng)用程序檢測“標(biāo)志”位置以驗證變量之前是否復(fù)制到閃存內(nèi)。該標(biāo)志可以存儲在特殊功能、非易失存儲器，或與變量共用存儲器，只要變量具有非零初始值(與空RAM地址區(qū)分開)。
2. 應(yīng)用程序?qū)⒚總€變量值從數(shù)據(jù)RAM復(fù)制到閃存，絕大多數(shù)帶有可重復(fù)寫操作閃存的MAXQ微控制器(如MAXQ2000)利用UROM_flashWrite函數(shù)實現(xiàn)。
3. 應(yīng)用程序在閃存中寫一個標(biāo)志，表明已經(jīng)存儲變量。

對于第二步，在后續(xù)的程序運行中，應(yīng)用程序必須將變量從閃存重新裝載到預(yù)先規(guī)定的數(shù)據(jù)RAM地址。

1. 應(yīng)用程序檢測閃存的標(biāo)志位置，以驗證已經(jīng)存儲變量。
2. 應(yīng)用程序利用UROM_copyBuffer子程序?qū)⒆兞繌拈W存復(fù)制到數(shù)據(jù)RAM的正確位置。

以下程序清單展示了利用MAXQ2000評估板的保存-恢復(fù)方案，該程序中，變量值存儲在閃存的7000h–71FFh地址內(nèi)。

$include(maxQ2000.inc)

;; Code memory (flash) : 0000h-7FFFh  (word addr)
;; Data memory (RAM)   : 0000h-03FFh  (word addr)

org 0000h

   ljump   start             ; Skip over password area

org 0020h

start:
   move    DPC, #1Ch         ; Set all pointers to word mode
   move    DP[0], #0F000h    ; Check first variable value (flag)
   lcall   UROM_moveDP0      ; 'move GR, @DP[0]' executed by Utility ROM
   move    Acc, GR
   cmp     #1234h
   jump    NE, copyToFlash

;; This is the "free-running" code, executed on subsequent power-ups, that copies
;; values from the flash back into their proper data segment locations.

   move    DP[0], #0F000h    ; Source: Flash location 7000h
   move    BP,    #0         ; Dest:   Start of RAM
   move    Offs,  #0
   move    LC[0], #100h      ; Copy 256 words
   lcall   UROM_copyBuffer

   jump    main

;; This is the first-pass code. A bit of a trick here; because MAX-IDE enters
;; and exits the loader separately when loading the code and data segment files,
;; the application is allowed to execute briefly before the data segment file
;; has been loaded. The first four lines under copyFlash ensure that the 
;; application waits for MAX-IDE to load the data segment file before continuing.

copyToFlash:
   move    DP[0], #0h        ; Wait for flag variable to be loaded by MAX-IDE.
   move    Acc, @DP[0]       ;    Note that this will reset the application; the
   cmp     #1234h            ;    data segment is not loaded while the application
   jump    NE, copyToFlash   ;    is still running.

   move    DP[0], #0         ; Start of RAM variable area
   move    A[4],  #7000h     ; Location in flash to write to
   move    LC[0], #100h      ; Store 256 words in flash 7000h-70FFh

copyToFlash_loop:
   move    DP[0], DP[0]      ; Refresh the data pointer to read values correctly,
                             ;    because calling UROM_flashWrite changes memory
                             ;    contexts and affects the cached @DP[0] value
   move    A[0], A[4]        ; Location to write
   move    A[1], @DP[0]++    ; Value to write (taken from RAM)
   lcall   UROM_flashWrite
   move    Acc, A[4]
   add     #1
   move    A[4], Acc
   djnz    LC[0], copyToFlash_loop

main:
   move    PD0,   #0FFh      ; Set all port 0 pins to output
   move    PO0,   #000h      ; Drive all port 0 pins low (LEDs off)

   move    DPC,   #1Ch       ; Set pointers to word mode
   move    DP[0], #varA
   move    Acc,   @DP[0]
   cmp     #1234h            ; Verify that the variable is set correctly
   jump    NE, fail

pass:
   move    PO0, #55h
   sjump   $

fail:
   sjump   $

segment data

org 0000h

varA:   
   dw  1234h

org 00FFh

varB:
   dw  5678h

end

結(jié)論

MAX-IDE提供的程序段和數(shù)據(jù)段工具能夠在數(shù)據(jù)存儲器中自動聲明變量地址，以起始值初始化這些變量?？梢岳脩?yīng)用程序在閃存中緩存這些變量，必要時恢復(fù)它們。這種方法允許基于匯編的應(yīng)用程序使用MAX-IDE提供的數(shù)據(jù)段自動裝載功能，無論微控制器是否連接JTAG調(diào)試器，都能保持工作。